**Arithmetic Mean**



=AVERAGE(*returns*)

**Standard Deviation**



=STDEV(*returns*)

**Annualised Mean**



=(1+*meanreturn*)^*numberofperiodsinyear*-1

**Annualised Standard Deviation**



=*standarddeviation*\*SQRT(*numberofperiodsinyear*)

**Probability < 0**



=COUNTIF(*returns*,"<0")/COUNT(*returns*)

**Value-at-Risk: Parametric**



=*mean*-NORMSINV(*confidence*)\**standarddeviation*

**Value-at-Risk: Empirical**



=PERCENTILE(*returns*,1-*confidence*)

**Conditional Value-at-Risk (Expected Shortfall): Parametric**



=*mean*-(EXP(-((NORMSINV(1-*confidence*))^2/2))/((1-*confidence*)\*SQRT(2\*PI())))\**stdev*

**Conditional Value-at-Risk (Expected Shortfall): Empirical**



*Find observations < VaR*

=IF(*observation*<=*VaR*,*observation*,"")

*Take average*

=AVERAGE(*observations<VaR*)

**Correlation**



=CORREL(INDEX(*assetreturns*,,*asset1*),INDEX(*assetreturns*,,*asset2*))

**Covariance**



=COVAR(INDEX(*assetreturns*,,*asset1*),INDEX(*assetreturns*,,*asset2*))

**Standard Deviation from Covariance**



=SQRT(INDEX(*covars*,*assetnum*,*assetnum*))

**Correlation from Covariance**



=*covariance12*/((INDEX(*stdevs*,1,*assetnum1*)\*INDEX(*stdevs*,1,*assetnum2*)))

**Portfolio Expected Return**



=SUMPRODUCT(*wts*,*means*)

**Portfolio Variance**



=MMULT(MMULT(*wts*,*covars*),TRANSPOSE(*wts*))

**Portfolio Standard Deviation:**



=SQRT(MMULT(MMULT(*wts*,*covars*),TRANSPOSE(*wts*)))

**Portfolio Tracking Error:**



=SQRT(MMULT(MMULT(*wts-wtsbench*,*covars*),TRANSPOSE(*wts-wtsbench*)))